|
| Run file for Fireworkz
|
Set      Fireworkz$Dir      <Obey$Dir>
Set      Fireworkz$ImageDir <Fireworkz$Dir>
SetMacro Fireworkz$Path     <Fireworkz$UserPath><Fireworkz$Dir>.User.,<Fireworkz$Dir>.Resource.<Fireworkz$EndPath>
|
IconSprites <Fireworkz$ImageDir>.!Sprites
|
Set File$Type_BDF Firewrkz
SetMacro Alias$@RunType_BDF   Run <Fireworkz$Dir>.!Run %%*0
SetMacro Alias$@PrintType_BDF Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_BE0 Recordz
SetMacro Alias$@RunType_BE0   Run <Fireworkz$Dir>.!Run %%*0
SetMacro Alias$@PrintType_BE0 Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_BE1 Resultz
SetMacro Alias$@RunType_BE1   Run <Fireworkz$Dir>.!Run %%*0
SetMacro Alias$@PrintType_BE1 Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_C1C Wordz
SetMacro Alias$@RunType_C1C   Run <Fireworkz$Dir>.!Run %%*0
SetMacro Alias$@PrintType_C1C Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_C1D FwrkzTem
SetMacro Alias$@RunType_C1D   Run <Fireworkz$Dir>.!Run -Template %%*0
SetMacro Alias$@PrintType_C1D Run <Fireworkz$Dir>.!Run -oPrint %%*0
|
Set File$Type_C1E FwrkzCmd
SetMacro Alias$@RunType_C1E   Run <Fireworkz$Dir>.!Run -Command %%*0
|
If "<File$Type_C32>"="" then Set File$Type_C32 RTF
If "<File$Type_DB0>"="" then Set File$Type_DB0 LotusWK1
If "<File$Type_DFE>"="" then Set File$Type_DFE CSV
|
SetEval Fireworkz$HasDOSFS 1
RMEnsure DOSFS 0.43 SetEval Fireworkz$HasDOSFS 0
If Fireworkz$HasDOSFS=1 then DOSMap TXT &FFF
If Fireworkz$HasDOSFS=1 then DOSMap RTF &C32
| If Fireworkz$HasDOSFS=1 then DOSMap WK1 &DB0 - doesn't accept numbers!
If Fireworkz$HasDOSFS=1 then DOSMap CSV &DFE
Unset Fireworkz$HasDOSFS
|
RMEnsure FontManager 2.42 Error 0 Fireworkz needs Outline FontManager 2.42 or later
|
RMEnsure Squash 0.00 If "<System$Path>"="" then Error 0 Unable to locate your System directory. Please use StartFwrkz on the Examples disc
RMEnsure Squash 0.00 RMLoad System:Modules.Squash
|
RMEnsure ColourTrans 0.52 If "<System$Path>"="" then Error 0 Unable to locate your System directory. Please use StartFwrkz on the Examples disc
RMEnsure ColourTrans 0.52 RMLoad System:Modules.Colours
RMEnsure ColourTrans 0.52 Error 0 The version of ColourTrans installed in your !System is too old. Fireworkz needs ColourTrans 0.52 or later
|
WimpSlot -min 32K -max 32K
Run Fireworkz:Loader -image <Fireworkz$ImageDir>.Resource.!Sprite
|
Set Fireworkz$CLibLoaded 1
RMEnsure SharedCLibrary 0.00 Set Fireworkz$CLibLoaded 0
If Fireworkz$CLibLoaded=0 then If "<System$Path>"="" then Error 0 Unable to locate your System directory. Please use StartFwrkz on the Examples disc
If Fireworkz$CLibLoaded=0 then RMLoad System:Modules.CLib
If Fireworkz$CLibLoaded=1 then RMEnsure SharedCLibrary 3.75 Error 0 You are already running a version of CLib which is too old. Fireworkz needs SharedCLibrary 3.75 or later
Unset Fireworkz$CLibLoaded
RMEnsure SharedCLibrary 3.75 Error 0 The version of CLib installed in your !System is too old. Fireworkz needs SharedCLibrary 3.75 or later
|
RMEnsure FPEmulator 2.80 If "<System$Path>"="" then Error 0 Unable to locate your System directory. Please use StartFwrkz on the Examples disc
RMEnsure FPEmulator 2.80 RMLoad System:Modules.FPEmulator
RMEnsure FPEmulator 2.80 Error 0 The version of FPEmulator installed in your !System is too old. Fireworkz needs FPEmulator 2.80 or later
|
RMEnsure Task 0.08 RMLoad Fireworkz:TaskX*
RMEnsure Task 0.08 Error 0 The version of Task found on your application resources path is too old. Fireworkz needs Task 0.08 or later
|
Run Fireworkz:ImageSlot <Fireworkz$ImageDir>.!RunImage 12K 64K
|
Run <Fireworkz$ImageDir>.!RunImage %*0